d1ad924216
* [AVR_ISP]: add AVR ISP Programmer FAP * [AVR_ISP]: add auto detect AVR chip * [AVR_ISP]: fix auto detect chip * [AVR_ISP]: fix fast write flash * AVR_ISP: auto set SPI speed * AVR_ISP: add clock 4Mhz on &gpio_ext_pa4 * AVR_ISP: fix "[CRASH][ISR 4] NULL pointer dereference" with no AVR chip connected * AVR_ISP: add AVR ISP Reader * AVR_ISP: add read and check I32HEX file * AVR_ISP: add write eerom, flash, fuse, lock byte * AVR_ISP: add gui Reader, Writer * Github: unshallow on decontamination * AVR_ISP: move to external * API: fix api_symbols * AVR_ISP: add wiring scene * GUI: model mutex FuriMutexTypeNormal -> FuriMutexTypeRecursive * AVR_ISP: add chip_detect view * AVR_ISP: refactoring gui ISP Programmer * AVR_ISP: add gui "Dump AVR" * AVR_ISP: add gui "Flash AVR" * AVR_ISP: fix navigation gui * GUI: model mutex FuriMutexTypeRecursive -> FuriMutexTypeNormal * AVR_ISP: fix conflicts * AVR_ISP: fix build * AVR_ISP: delete images * AVR_ISP: add images * AVR_ISP: fix gui * AVR_ISP: fix stuck in navigation * AVR_ISP: changing the Fuse bit recording logic * AVR_ISP: fix read/write chips with memory greater than 64Kb * AVR_ISP: fix auto set speed SPI * AVR_ISP: fix gui * ISP: switching on +5 volts to an external GPIO Co-authored-by: Aleksandr Kutuzov <alleteam@gmail.com>
72 lines
1.7 KiB
Python
72 lines
1.7 KiB
Python
Import("env")
|
|
|
|
from fbt.version import get_fast_git_version_id
|
|
|
|
|
|
env.Append(
|
|
CPPPATH=[
|
|
"#/lib/toolbox",
|
|
],
|
|
SDK_HEADERS=[
|
|
File("manchester_decoder.h"),
|
|
File("manchester_encoder.h"),
|
|
File("path.h"),
|
|
File("random_name.h"),
|
|
File("sha256.h"),
|
|
File("crc32_calc.h"),
|
|
File("dir_walk.h"),
|
|
File("md5.h"),
|
|
File("args.h"),
|
|
File("saved_struct.h"),
|
|
File("version.h"),
|
|
File("float_tools.h"),
|
|
File("value_index.h"),
|
|
File("tar/tar_archive.h"),
|
|
File("stream/stream.h"),
|
|
File("stream/file_stream.h"),
|
|
File("stream/string_stream.h"),
|
|
File("stream/buffered_file_stream.h"),
|
|
File("protocols/protocol_dict.h"),
|
|
File("pretty_format.h"),
|
|
File("hex.h"),
|
|
],
|
|
)
|
|
|
|
|
|
libenv = env.Clone(tools=["fbt_version"], FW_LIB_NAME="toolbox")
|
|
libenv.ApplyLibFlags()
|
|
|
|
|
|
# Git Version management
|
|
version_depends = []
|
|
version_id_data = get_fast_git_version_id()
|
|
if version_id_data:
|
|
version_depends = Value(version_id_data)
|
|
|
|
# Only invoke version generator if preliminary check target (version_depends) has changed
|
|
build_version = libenv.VersionBuilder(
|
|
Dir("."),
|
|
version_depends,
|
|
)
|
|
|
|
fw_version_json = libenv.InstallAs(
|
|
"${BUILD_DIR}/${FIRMWARE_BUILD_CFG}.json", "version.json"
|
|
)
|
|
Alias("version_json", fw_version_json)
|
|
env.Append(FW_VERSION_JSON=fw_version_json)
|
|
|
|
# Default(fw_version_json)
|
|
|
|
|
|
if not version_depends:
|
|
libenv.Precious(build_version)
|
|
libenv.AlwaysBuild(build_version)
|
|
|
|
sources = libenv.GlobRecursive("*.c")
|
|
|
|
libenv.Append(CPPPATH=[libenv.Dir(".")])
|
|
|
|
lib = libenv.StaticLibrary("${FW_LIB_NAME}", sources)
|
|
libenv.Install("${LIB_DIST_DIR}", lib)
|
|
Return("lib")
|