04e50c9f89
* fbt: replaced debug dir paths with FBT_DEBUG_DIR * scripts: updated requirements.txt * fbt: fixed wrong import * fbt: removed delayed import for file2image * fbt: added UPDATE_BUNDLE_DIR internal var * fbt: cleaner internal management of extapps * applications: added fap_libs for core apps to link with resources when building with --extra-ext-apps * fbt: removed deprecation stub for faps * fbt: added quotation for icons build cmd * fbt: reworked BUILD_DIR & fap work dir handling; fap debug: using debug elf path from fbt * fbt: explicit LIB_DIST_DIR
90 lines
2.3 KiB
Plaintext
90 lines
2.3 KiB
Plaintext
from SCons.Platform import TempFileMunge
|
|
from fbt.util import (
|
|
tempfile_arg_esc_func,
|
|
single_quote,
|
|
wrap_tempfile,
|
|
extract_abs_dir_path,
|
|
)
|
|
|
|
import os
|
|
import multiprocessing
|
|
|
|
Import("VAR_ENV")
|
|
|
|
forward_os_env = {
|
|
# Import PATH from OS env - scons doesn't do that by default
|
|
"PATH": os.environ["PATH"],
|
|
}
|
|
# Proxying CI environment to child processes & scripts
|
|
variables_to_forward = [
|
|
# CI/CD variables
|
|
"WORKFLOW_BRANCH_OR_TAG",
|
|
"DIST_SUFFIX",
|
|
# Python & other tools
|
|
"HOME",
|
|
"APPDATA",
|
|
"PYTHONHOME",
|
|
"PYTHONNOUSERSITE",
|
|
"TMP",
|
|
"TEMP",
|
|
# Colors for tools
|
|
"TERM",
|
|
]
|
|
if proxy_env := GetOption("proxy_env"):
|
|
variables_to_forward.extend(proxy_env.split(","))
|
|
|
|
for env_value_name in variables_to_forward:
|
|
if environ_value := os.environ.get(env_value_name, None):
|
|
forward_os_env[env_value_name] = environ_value
|
|
|
|
|
|
coreenv = VAR_ENV.Clone(
|
|
tools=[
|
|
"fbt_tweaks",
|
|
(
|
|
"crosscc",
|
|
{
|
|
"toolchain_prefix": "arm-none-eabi-",
|
|
"versions": VAR_ENV["FBT_TOOLCHAIN_VERSIONS"],
|
|
},
|
|
),
|
|
"python3",
|
|
"sconsmodular",
|
|
"sconsrecursiveglob",
|
|
"ccache",
|
|
],
|
|
TEMPFILE=TempFileMunge,
|
|
MAXLINELENGTH=2048,
|
|
PROGSUFFIX=".elf",
|
|
ENV=forward_os_env,
|
|
SINGLEQUOTEFUNC=single_quote,
|
|
ABSPATHGETTERFUNC=extract_abs_dir_path,
|
|
# Setting up temp file parameters - to overcome command line length limits
|
|
TEMPFILEARGESCFUNC=tempfile_arg_esc_func,
|
|
ROOT_DIR=Dir("#"),
|
|
FBT_SCRIPT_DIR="${ROOT_DIR}/scripts",
|
|
)
|
|
|
|
# If DIST_SUFFIX is set in environment, is has precedence (set by CI)
|
|
if os_suffix := os.environ.get("DIST_SUFFIX", None):
|
|
coreenv.Replace(
|
|
DIST_SUFFIX=os_suffix,
|
|
)
|
|
|
|
# Default value for commandline options
|
|
|
|
SetOption("num_jobs", multiprocessing.cpu_count())
|
|
## NB - disabled both caches since they seem to do more harm then good in our case
|
|
# Avoiding re-scan of all sources on every startup
|
|
# SetOption("implicit_cache", True)
|
|
# SetOption("implicit_deps_unchanged", True)
|
|
# More aggressive caching
|
|
SetOption("max_drift", 1)
|
|
# Random task queue - to discover isses with build logic faster
|
|
# SetOption("random", 1)
|
|
|
|
wrap_tempfile(coreenv, "LINKCOM")
|
|
wrap_tempfile(coreenv, "ARCOM")
|
|
|
|
Return("coreenv")
|